* DIODES INCORPORATED AND ITS AFFILIATED COMPANIES AND SUBSIDIARIES (COLLECTIVELY, "DIODES") 
* PROVIDE THESE SPICE MODELS AND DATA (COLLECTIVELY, THE "SM DATA") "AS IS" AND WITHOUT ANY 
* REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY 
* OR FITNESS FOR A PARTICULAR PURPOSE, ANY WARRANTY ARISING FROM COURSE OF DEALING OR COURSE OF 
* PERFORMANCE, OR ANY WARRANTY THAT ACCESS TO OR OPERATION OF THE SM DATA WILL BE UNINTERRUPTED, 
* OR THAT THE SM DATA OR ANY SIMULATION USING THE SM DATA WILL BE ERROR FREE. TO THE MAXIMUM 
* EXTENT PERMITTED BY LAW, IN NO EVENT WILL DIODES BE LIABLE FOR ANY DIRECT OR INDIRECT, 
* SPECIAL, INCIDENTAL, PUNITIVE OR CONSEQUENTIAL DAMAGES ARISING OUT OF OR IN CONNECTION WITH 
* THE PRODUCTION OR USE OF SM DATA, HOWEVER CAUSED AND UNDER WHATEVER CAUSE OF ACTION OR THEORY 
* OF LIABILITY BROUGHT (INCLUDING, WITHOUT LIMITATION, UNDER ANY CONTRACT, NEGLIGENCE OR OTHER 
* TORT THEORY OF LIABILITY), EVEN IF DIODES HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES, 
* AND DIODES' TOTAL LIABILITY (WHETHER IN CONTRACT, TORT OR OTHERWISE) WITH REGARD TO THE SM 
* DATA WILL NOT, IN THE AGGREGATE, EXCEED ANY SUMS PAID BY YOU TO DIODES FOR THE SM DATA.



*TITLE=AP431i MACROMODEL
*SIMULATOR=DIODES, SIMETRIX and PSPICE
*VERSION=1
*PIN_ORDER   1:Ka, 2:Ref, 3:An
*
*

.subckt AP431i Ka Ref An
* Connections  Ka Ref An
*
L_IC1_L3         Ka $N_0002  2n  
L_IC1_L4         Ref $N_0004  2n 
Q_IC1_Q3  $N_0002 $N_0004 $N_0005  qn M=9.7
R_IC1_R1  $N_0005 $N_0006 9.7K
R_IC1_R2  $N_0005 $N_0007 9.7K
R_IC1_R3  $N_0005 $N_0008 37.6K
Q_IC1_Q16 $N_0009 $N_0009 $N_0006  qp M=1
Q_IC1_Q0  $N_0010 $N_0009 $N_0007  qp M=1
R_IC1_R44 $N_0009 $N_0011 0.5K
Q_IC1_Q21 $N_0011 $N_0008 $N_0012  qn M=3.23
L_IC1_L2  An $N_0012  2n 
R_IC1_R0  $N_0008 $N_0013 1.88K
Q_IC1_Q24 $N_0013 $N_0008 $N_0012   qn M=16.15
R_IC1_R50 $N_0013 $N_0014 21K
Q_IC1_Q23 $N_0010 $N_0014 $N_0012  qn M=32.3
C_IC1_C1  $N_0010 $N_0002  7.4p  
Q_IC1_Q14 $N_0015 $N_0010 $N_0012  qn M=6.4
Q_IC1_Q9  $N_0015 $N_0015 $N_0002  qp M=1
Q_IC1_Q15 $N_0016 $N_0015 $N_0002  qp M=3
Q_IC1_Q26 $N_0016 $N_0016 $N_0004  qn M=8
Q_IC1_Q7  $N_0016 $N_0016 $N_0017  qn M=4
R_IC1_R20 $N_0017 $N_0018 8.5K
R_IC1_R21 $N_0018 $N_0019 3K
Q_IC1_Q6  $N_0019 $N_0019 $N_0012  qn M=5.6
R_IC1_R8  $N_0019 $N_0012 52K
C_IC1_C2  $N_0016 $N_0002  7.6p
Q_IC1_Q2  $N_0002 $N_0016 $N_0018  qn M=36
Q_IC1_Q1  $N_0002 $N_0018 $N_0012  qn M=166


.model qn NPN
***********************  DC  *********************************
+      IS=2.591E-17        BF=154.4776              NF=1.0
+      VAF=341.1118      IKF=3.2586E-03        ISE=2.6702E-17
+      NE=1.3141            BR=0.0403                NR=0.9921
+      VAR=11.3432       IKR=2.2258E-04        ISC=1.7561E-15
+      NC=1.1645           RB=506.9155             IRB=1.0368E-05
+      RBM=100.1645     RE=2.5875                RC=1180
+      Tref=27.0          
********************** Capacitance ***************************
+      CJE=9.88E-14       VJE=0.7404          MJE=0.3691
+      CJC=7.67E-14       VJC=0.5511          MJC=0.3769
+      CJS=4.91E-13       VJS=0.443           MJS=0.2484
+      FC=0.75               XCJC=0.3
********************* Transit Time ***************************
+      TF=3.98E-10         XTF=38.61          VTF=43.06
+      ITF=0.1143          TR=3.98E-8         PTF=29.86
********************* Temperature ****************************
+      XTB=1.25           XTI=5.2          EG=1.11    
********************* Noise **********************************
+      KF=0.00              AF=1.0
*#################################################################
.model qp PNP
***********************  DC  *********************************
+       IS=9.1059E-17     BF=576.0            NF=1.0
+       VAF=72.694        IKF=2.946E-05       ISE=6.327E-16
+       NE=1.7475         BR=85.867           NR=1.0053
+       VAR=13.078        IKR=1.575E-05       ISC=4.96E-17
+       NC=1.234          RB=2.9407E+03       IRB=1.8253E-07
+       RBM=204.78        RE=51.3374          RC=419.9798 
+       Tref=27.0          
********************** Capacitance ***************************
+       CJE=3.15E-14      VJE=0.5511          MJE=0.3769
+       CJC=3.03E-13      VJC=0.5511          MJC=0.3769
+       CJS=8.1E-13       VJS=0.443           MJS=0.2484
+       FC=0.75           XCJC=0.08
********************* Transit Time ***************************
+       TF=2.01E-08        XTF=1.0335         VTF=8.5728
+       ITF=0.0337         TR=10E-8           PTF=0.00
********************* Temperature ****************************
+       XTB=0.095          XTI=6.6053          EG=1.11      
********************* Noise **********************************
+       KF=0.00            AF=1.0
*#################################################################

.ends AP431i