* DIODES INCORPORATED AND ITS AFFILIATED COMPANIES AND SUBSIDIARIES (COLLECTIVELY, "DIODES") 
* PROVIDE THESE SPICE MODELS AND DATA (COLLECTIVELY, THE "SM DATA") "AS IS" AND WITHOUT ANY 
* REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY 
* OR FITNESS FOR A PARTICULAR PURPOSE, ANY WARRANTY ARISING FROM COURSE OF DEALING OR COURSE OF 
* PERFORMANCE, OR ANY WARRANTY THAT ACCESS TO OR OPERATION OF THE SM DATA WILL BE UNINTERRUPTED, 
* OR THAT THE SM DATA OR ANY SIMULATION USING THE SM DATA WILL BE ERROR FREE. TO THE MAXIMUM 
* EXTENT PERMITTED BY LAW, IN NO EVENT WILL DIODES BE LIABLE FOR ANY DIRECT OR INDIRECT, 
* SPECIAL, INCIDENTAL, PUNITIVE OR CONSEQUENTIAL DAMAGES ARISING OUT OF OR IN CONNECTION WITH 
* THE PRODUCTION OR USE OF SM DATA, HOWEVER CAUSED AND UNDER WHATEVER CAUSE OF ACTION OR THEORY 
* OF LIABILITY BROUGHT (INCLUDING, WITHOUT LIMITATION, UNDER ANY CONTRACT, NEGLIGENCE OR OTHER 
* TORT THEORY OF LIABILITY), EVEN IF DIODES HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES, 
* AND DIODES' TOTAL LIABILITY (WHETHER IN CONTRACT, TORT OR OTHERWISE) WITH REGARD TO THE SM 
* DATA WILL NOT, IN THE AGGREGATE, EXCEED ANY SUMS PAID BY YOU TO DIODES FOR THE SM DATA.



*ZETEX ZRC250 Spice Model v1.0 Last Revised 11/07/06
    *
    *NOTE: This is a simplified model.  Confirm
    *any design using a physical circuit.
    *
    .SUBCKT ZRC250 1 3
    *Connections  Vz Gnd
    *
    *Quiescent current
    R1 1 49 320E3
    R2 49 3 315.2E3
    C1 49 1 4.5e-12
    E1 50 3 49 3 1
    D8 50 51 Dmod1
    Rq 51 52 Rmod2 70E3
    Vq 52 3 0
    F1 1 3 Vq 1
    *
    *Reference voltage
    Iref 3 21 1.2405E-3
    Rref 21 3 Rmod1 1000
    *
    *Gain
    G2 3 31 49 21 1e-7
    Rt2  3 31 100E6
    Rt3  3 32 3E6
    Ct1 31 32 1.5E-13
    D3 31 3  Dmod1
    D4 3 31  Dmod1
    *
    *Output
    G3 41 3 31 3 0.3
    Rc1 6 5 10
    D6 3 41 Dmod1
    D7 3 6 Dmod1
    L1 1 6 10nH
    D9 5 41 Dmod2
    *
    .MODEL Qmod1 NPN BF=220 CJC=3E-12 CJE=3E-12
    .MODEL Rmod1 RES (TC1=3.8e-5 TC2=-1e-7)
    .MODEL Rmod2 RES (TC1=1.7E-3 TC2=0)
    .MODEL Dmod1 D IS=5E-15 RS=4 BV=22
    .MODEL Dmod2 D IS=1E-18 RS=.01
    .ENDS  ZRC250
    *
    *$
    *