* DIODES INCORPORATED AND ITS AFFILIATED COMPANIES AND SUBSIDIARIES (COLLECTIVELY, "DIODES") 
* PROVIDE THESE SPICE MODELS AND DATA (COLLECTIVELY, THE "SM DATA") "AS IS" AND WITHOUT ANY 
* REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY 
* OR FITNESS FOR A PARTICULAR PURPOSE, ANY WARRANTY ARISING FROM COURSE OF DEALING OR COURSE OF 
* PERFORMANCE, OR ANY WARRANTY THAT ACCESS TO OR OPERATION OF THE SM DATA WILL BE UNINTERRUPTED, 
* OR THAT THE SM DATA OR ANY SIMULATION USING THE SM DATA WILL BE ERROR FREE. TO THE MAXIMUM 
* EXTENT PERMITTED BY LAW, IN NO EVENT WILL DIODES BE LIABLE FOR ANY DIRECT OR INDIRECT, 
* SPECIAL, INCIDENTAL, PUNITIVE OR CONSEQUENTIAL DAMAGES ARISING OUT OF OR IN CONNECTION WITH 
* THE PRODUCTION OR USE OF SM DATA, HOWEVER CAUSED AND UNDER WHATEVER CAUSE OF ACTION OR THEORY 
* OF LIABILITY BROUGHT (INCLUDING, WITHOUT LIMITATION, UNDER ANY CONTRACT, NEGLIGENCE OR OTHER 
* TORT THEORY OF LIABILITY), EVEN IF DIODES HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES, 
* AND DIODES' TOTAL LIABILITY (WHETHER IN CONTRACT, TORT OR OTHERWISE) WITH REGARD TO THE SM 
* DATA WILL NOT, IN THE AGGREGATE, EXCEED ANY SUMS PAID BY YOU TO DIODES FOR THE SM DATA.



*ZETEX ZXMHC3A01T8 Spice Model v1.0 Last Revised 8/7/05
    *
    .SUBCKT ZXMHC3A01T8 51 52 53 54 55 56 57 58
    *connections
    *51=pin1=G3
    *52=pin2=S2,S3
    *53=pin3=G2
    *54=pin4=G1
    *55=pin5=D1,D2
    *56=pin6=S1,S4
    *57=pin7=D3,D4
    *58=pin8=G4
    *
    L1 1 51 2.3e-9
    L2a 62 2 1.3e-9
    L2b 72 2 1.3e-9
    L2c 2 52 1e-9
    L3 3 53 2.3e-9
    L4 4 54 2.3e-9
    L5 5 55 1.5e-9
    L6a 66 6 1.3e-9
    L6b 76 6 1.3e-9
    L6c 6 56 1e-9
    L7 7 57 1.5e-9
    L8 8 58 2.3e-9
    M11 16 12 62 62 Nnmod
    M12 62 12 62 16 Npmod
    RG1 3 12 5
    RIN1 12 62 1E12
    RD1 5 16 Nrmod 0.08
    RL1 5 62 3E9
    C11 12 62 8.5E-12
    C21 5 3 3E-12
    D11 62 5  Ndmod
    M21 26 22 72 72 Nnmod
    M22 72 22 72 26 Npmod
    RG2 1 22 5
    RIN2 22 72 1E12
    RD2 7 26 Nrmod 0.08
    RL2 7 72 3E9
    C12 22 72 8.5E-12
    C22 7 1 3E-12
    D12 72 7  Ndmod
    M31 36 32 66 66 Ppmod
    M32 66 32 66 36 Pnmod
    RG3 4 32 10
    RIN3 32 66 1E9
    RD3 5 36 Prmod 0.05
    RL3 5 66 3E9
    C13 32 66 8.5E-12
    C23 5 4 5E-12
    D13 5 66  Pdmod
    M41 46 42 76 76 Ppmod
    M42 76 42 76 46 Pnmod
    RG4 8 42 10
    RIN4 42 76 1E9
    RD4 7 46 Prmod 0.05
    RL4 76 7 3E9
    C14 42 76 8.5E-12
    C24 7 8 5E-12
    D14 7 76  Pdmod
    .MODEL Nnmod NMOS (LEVEL=3 TOX=5.5E-8 NSUB=5E17 L=1.16E-6 W=0.28  VTO=2.3
    +KP=15E-5 RS=.045 NFS=2E11 KAPPA=0.06 UO=650 IS=1E-15 N=10)
    .MODEL Npmod PMOS (LEVEL=3 TOX=5.5E-8 NSUB=1.5E16 L=1.3E-6 W=0.13  
    +TPG=-1 IS=1E-15 N=10)
    .MODEL Ndmod D (IS=6E-13 RS=.025 IKF=0.1 TRS1=1.5e-3
    +CJO=85e-12  BV=33)
    .MODEL Nrmod RES (TC1=4.2e-3 TC2=1E-5)
    .MODEL Ppmod PMOS (LEVEL=3 TOX=5.5E-8 NSUB=1E17 L=1.2E-6 W=0.33 
    +VTO=-1.9 KP=2E-5 RS=.05 NFS=2E11 KAPPA=0.06 UO=650 IS=1E-15 N=10)
    .MODEL Pnmod NMOS (LEVEL=3 TOX=5.5E-8 NSUB=2E16 L=1.4E-6 W=0.19 
    +TPG=-1 IS=1E-15 N=10)
    .MODEL Pdmod D (IS=6E-13 RS=.025 IKF=0.1 TRS1=1.5e-3
    +CJO=65e-12  BV=33)
    .MODEL Prmod RES (TC1=5.5e-3 TC2=1.5E-5)
    .ENDS 
    *
    *$
    *