* DIODES INCORPORATED AND ITS AFFILIATED COMPANIES AND SUBSIDIARIES (COLLECTIVELY, "DIODES") 
* PROVIDE THESE SPICE MODELS AND DATA (COLLECTIVELY, THE "SM DATA") "AS IS" AND WITHOUT ANY 
* REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY 
* OR FITNESS FOR A PARTICULAR PURPOSE, ANY WARRANTY ARISING FROM COURSE OF DEALING OR COURSE OF 
* PERFORMANCE, OR ANY WARRANTY THAT ACCESS TO OR OPERATION OF THE SM DATA WILL BE UNINTERRUPTED, 
* OR THAT THE SM DATA OR ANY SIMULATION USING THE SM DATA WILL BE ERROR FREE. TO THE MAXIMUM 
* EXTENT PERMITTED BY LAW, IN NO EVENT WILL DIODES BE LIABLE FOR ANY DIRECT OR INDIRECT, 
* SPECIAL, INCIDENTAL, PUNITIVE OR CONSEQUENTIAL DAMAGES ARISING OUT OF OR IN CONNECTION WITH 
* THE PRODUCTION OR USE OF SM DATA, HOWEVER CAUSED AND UNDER WHATEVER CAUSE OF ACTION OR THEORY 
* OF LIABILITY BROUGHT (INCLUDING, WITHOUT LIMITATION, UNDER ANY CONTRACT, NEGLIGENCE OR OTHER 
* TORT THEORY OF LIABILITY), EVEN IF DIODES HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES, 
* AND DIODES' TOTAL LIABILITY (WHETHER IN CONTRACT, TORT OR OTHERWISE) WITH REGARD TO THE SM 
* DATA WILL NOT, IN THE AGGREGATE, EXCEED ANY SUMS PAID BY YOU TO DIODES FOR THE SM DATA.



*
*DIODES_INC_SPICE_MODEL
*ORIGIN=DZSL_DPG
*SIMULATOR=PSPICE
*DATE=08/12/2009
*VERSION=2
*PIN_ORDER         D G S
*
.SUBCKT ZXMS6004FF 1 2 3
M1 31 40 33 33 Mmod1
M2 4 4 21 3 Mmod2 M=40
M3 41 37 38 38 Mmod3
M6 14 51 3 3 Mmod2 M=400
R1 2 4 60E3
R2 41 31 0.01
R3 3 33 0.35
R4 41 3 10E6
R5 37 3 20E3
R7 2 12 600
R8 12 10 50E3
R10 50 3 1000
R11 12 52 98E3
R12 3 52 2E3
R13 51 52 120E3
R14 4 14 500
R15 110 111 Rmod1 1
C1 4 33 200E-12
C2 4 31 50E-12
C3 35 31 200E-12
C4 52 3 50E-12
S1 21 3 41 22 Smod1
S2 4 35 31 4 Smod2
S3 34 35 31 4 Smod3
E1 22 3 2 3 0.22
E2 34 33 4 33 1
E3 19 3 103 109 4E-3
E4 19 50 value={V(10)-V(52)-0.50}
E5 51 3 value={V(12)*((TANH(V(50)*100)+1)/2)}
E6 4 40 100 3 4.2e-3
E7 109 3 value={(V(110)*1000)+27}
D1 5 2 Dmod1
D2 5 3 Dmod1
D3 38 4 Dmod3
D4 3 12 Dmod4
D5 13 3 Dmod6
D6 10 13 Dmod6
D7 37 41 Dmod7
D8 3 41 Dmod8
V1 1 41 0
V2 3 111 1
I1 3 110 1
*
* Distributed Thermal Model 15mm x 15mm x 1.6mm FR4 1oz Cu
* To enable thermal feedback for transient analysis only change **G1 to G1
* Transient junction temperature may be observed at node 100 where 1V=1°C
*
**G1 3 100 value={ABS( I(V1) * V(1,3) ) }
R21 100 101 0.23
R22 101 102 0.275
R23 102 103 1.265
R24 103 104 2.875
R25 104 105 10.925
R26 105 106 28.175
R27 106 107 29.67
R28 107 108 11.73
R29 108 109 67.85
C21 100 101 2.17E-5
C22 101 102 1.09E-4
C23 102 103 2.37E-4
C24 103 104 6.61E-4
C25 104 105 2.563E-3
C26 105 106 6.744E-3
C27 106 107 2.7974E-2
C28 107 108 0.8525
C29 108 109 0.8843
*
.MODEL Mmod1 NMOS (LEVEL=1 VTO=1.35 IS=1E-15 KP=10)
.MODEL Mmod2 NMOS (LEVEL=1 VTO=2.7 )
.MODEL Mmod3 NMOS (LEVEL=1 VTO=1.95 IS=1E-15 KP=0.001 RS=10)
.MODEL Dmod1 D (RS=11 BV=11)
.MODEL Dmod2 D (RS=1 BV=5 CJO=10p)
.MODEL Dmod3 D (RS=10 BV=12)
.MODEL Dmod4 D (RS=10 BV=6)
.MODEL Dmod5 D (RS=10 BV=7)
.MODEL Dmod6 D (IS=1E-14 RS=10 BV=12)
.MODEL Dmod7 D (RS=1 BV=65)
.MODEL Dmod8 D (IS=1E-13 RS=0.05 N=1.005 BV=90 CJO=212E-12 M=0.5 VJ=0.75)
.MODEL Smod1 VSWITCH RON=100 ROFF=1E6  VON=0.5 VOFF=0
.MODEL Smod2 VSWITCH RON=1 ROFF=1E6  VON=-0.5 VOFF=0.5
.MODEL Smod3 VSWITCH RON=1 ROFF=1E6  VON=0.5 VOFF=-0.5
.MODEL Rmod1 RES (TC1=1e-3)
.ENDS
*
*$